Hỏi đáp [Solved] Lấy tất cả tên biến và hàm func có trong file au3

Như đề bài thì có cách nào lấy được tên biến + tên hàm không các bác :/
Mình có tìm thử trên google mà hình như code không hoạt động thì phải !

 

admin trên autoitscript.com có tổng hợp tất cả các hàm parse Au3 code nè cậu: https://www.autoitscript.com/forum/topic/152146-au3-script-parsing-related-functions/ nhưng độ chính xác tầm 90% thôi

còn muốn chính xác gần tuyệt đối thì sử dụng bộ udf của Matt: https://github.com/MattDiesel/Ault

 

có cách này chỉ lấy phần biến do mình code và loại bỏ các biến mặc định của Autoit như $GUI_SHOW,$ES_PASSWORD,... không bác ?

 

cách này là của riêng tớ nha, k biết có tối ưu k nhưng nói chung chạy ổn ^^:
giờ tớ sẽ code 1 đoạn code để lấy tất cả các biến mặc định trong thư mục Inlcude:

Mã (AutoIt):

#include <Array.au3>
#include <File.au3>

Local $IncludeFolder = "C:\AutoIt3\Include" ;Thay thư mục Include vào, hoặc google tìm code Get đường dẫn thư mục Include
Local $TongHopBienConstant
Local $array_Include = _FileListToArray($IncludeFolder, '*Constants.au3', $FLTA_FILES, True)
_ArrayDisplay($array_Include, 'Constants Au3')
For $i = 1 To $array_Include[0]
    $TongHopBienConstant &= FileRead($array_Include[$i]) & @CRLF
Next
$TongHopBienConstant = StringRegExp($TongHopBienConstant, "(?i)Global Const (\$\w+)", 3)
_ArrayDisplay($TongHopBienConstant)
$TongHopBienConstant = "|" & _ArrayToString($TongHopBienConstant) & "|"
MsgBox(0, "Tập hợp tất cả biến Constant", $TongHopBienConstant)

Sau khi đã lấy được các tên biến trong source code và lưu chúng trong 1 mảng, cậu sẽ dùng 1 vòng lặp để kiểm tra tên biến đó có nằm trong $TongHopBienConstant hay k bằng lệnh:

Mã (AutoIt):

StringInStr($TongHopBienConstant, "|" & PhầntửChứaTênBiến & "|", 0, 1)

để lọc bỏ biến mặc định là xong ^^

 

Không biết sao đã lọc rồi mà vẫn còn thằng $GUI_EVENT_CLOSE bác ơi o.0 không biết còn biến nào sót nữa ko @@

 

cậu ClipPut($TongHopBienConstant) rồi paste vào notepad kiểm tra xem có $GUI_EVENT_CLOSE k. nếu có thì có lẽ do lọc sai chỗ nào r ^^

 

tớ mới thử đúng là k có tên biến đó, chắc _FileListToArray thiếu thư viện, tớ coi lại chút đã

 

trời, ngoài Contants.au3 còn có ConstantsEx.au3 nữa ^^

 

cậu sửa lại thành: _FileListToArray($IncludeFolder, '*Constants*.au3', $FLTA_FILES, True) nha

 

Sao mình vẫn ko hiểu cái UDF của Matt cho lắm, mình đã thế vào các kiểu mà nó vẫn trả về lỗi :<

 

chiều tớ về tớ quăng cho cậu UDF tớ rút gọn lại của Matt, rất dễ sử dụng

 

vâng, mình cảm ơn bác trước ^^

 

đây nha

 

Sao cái UDF của bác mình chạy thì ko biết sao nó cũng hiện 1 số biến mặc định của autoit :(:( $GUI_CHECK_KEY,$GUI_UNCHECKED,$GUI_EVENT_CLOSE,... bác ạ :(

 

UDF là để parse source code autoit ra biến, hàm, chuỗi, comment.... chứ đâu liên quan gì việc phân tích nó là biến do cậu viết với biến Global Const trong Include đâu cậu. sau khi parse ra biến cậu phải kết hợp với code mình đăng ở cmt #4 để lọc ra chứ

 

nếu cậu còn bối rối thì tham khảo code đã kết hợp này nha, đơn giản mà

Mã (AutoIt):

#include <_Lexer_UDF.au3>
#include <Array.au3>
#include <File.au3>


#Region Tổng hợp Global Const
    Local $IncludeFolder = "H:\Programming\AutoIt3\Include" ;Thay thư mục Include vào, hoặc google tìm code Get đường dẫn thư mục Include
    Local $TongHopBienConstant
    Local $array_Include = _FileListToArray($IncludeFolder, '*Constants*.au3', $FLTA_FILES, True)
    ;_ArrayDisplay($array_Include, 'Constants Au3')
    For $i = 1 To $array_Include[0]
        $TongHopBienConstant &= FileRead($array_Include[$i]) & @CRLF
    Next
    $TongHopBienConstant = StringRegExp($TongHopBienConstant, "(?i)Global Const (\$\w+)", 3)
    ;_ArrayDisplay($TongHopBienConstant)
    $TongHopBienConstant = "|" & _ArrayToString($TongHopBienConstant) & "|"
    ;MsgBox(0, "Tập hợp tất cả biến Constant", $TongHopBienConstant)
#EndRegion


Local $aFuncs[0]
Local $aVars[0]
Local $aString[0]
Local $aNumbers[0]


Local $Path_SourceCode = FileOpenDialog("Select au3 file", "", "au3(*.au3)")
If @error Then Exit

Local $aTok, $Line_Parsing = 0
Local $Data_SourceCode = FileRead($Path_SourceCode)
Local $AutoIt_Lexer = _Ault_CreateLexerFromString($Path_SourceCode, $Data_SourceCode & @CRLF, 0)
Do
    $aTok = _Ault_LexerStep($AutoIt_Lexer)
    If @error Then Exit MsgBox(16, 'Error: ' & @error, 'Có đoạn source code khiến chương trình không quét được' & @CRLF & 'trong phạm vi dòng thứ ' & ($Line_Parsing + 1))
    ;---------------------------------------------------
    Switch $aTok[$AL_TOKI_TYPE] ;Phân Loại biến-Số-CHuỗi-Hàm....
        Case $AL_TOK_EOL ;Dòng mới
            $Line_Parsing += 1 ;dòng này dùng để debug hoặc đếm số dòng mới

        Case $AL_TOK_KEYWORD ;Keyword

        Case $AL_TOK_MACRO ;Macro

        Case $AL_TOK_FUNC ;Hàm mặc định
         
        Case $AL_TOK_WORD ;Hàm do mình tạo hoặc hàm trong UDF
            _ArrayAdd($aFuncs, $aTok[$AL_TOKI_DATA])

        Case $AL_TOK_STR ;Chuỗi
            _ArrayAdd($aString, $aTok[$AL_TOKI_DATA], 0, ChrW(0x9999)) ;Phải thay đổi $delim của hàm _ArrayAdd thành 1 ký tự thật đặc biệt để không bị lỗi tách chuỗi sai
         
        Case $AL_TOK_VARIABLE ;Biến
            If Not StringInStr($TongHopBienConstant, "|" & $aTok[$AL_TOKI_DATA] & "|", 0, 1) Then _ArrayAdd($aVars, $aTok[$AL_TOKI_DATA])

        Case $AL_TOK_NUMBER ;Số
            _ArrayAdd($aNumbers, $aTok[$AL_TOKI_DATA])

        Case $AL_TOK_COMMENT ;Comment dạng ; hoặc #cs...#ce

        Case $AL_TOK_PREPROC ;Các param # như: #Region, #RequireAdmin, #Au3Stripper_Ignore_Funcs....

    EndSwitch
Until $aTok[$AL_TOKI_TYPE] = 0 ;$AL_TOK_EOF


$aFuncs = _ArrayUnique($aFuncs) ;lọc trùng
$aVars = _ArrayUnique($aVars) ;lọc trùng
$aNumbers = _ArrayUnique($aNumbers) ;lọc trùng

_ArrayDisplay($aFuncs, "Tất cả hàm User trong code")
_ArrayDisplay($aString, "Tất cả Chuỗi trong code")
_ArrayDisplay($aVars, "Tất cả biến trong code")
_ArrayDisplay($aNumbers, "Tất cả số trong code")

 

Để tiết kiệm thời gian chạy code cậu có thể lưu $TongHopBienConstant ra txt, khi chạy code thì chỉ việc đọc file txt (FileRead) chứa tất cả các biến Global Const này thôi cho đỡ nặng code ^^

 

vâng thanks bác nhiều lắm ! không biết bác có fb ko cho mình xin để học hỏi với ạ ^^